SkunkWorks - Home

Automatizar la eliminación de copias de seguridad

Infraestructura

Como automatizar la eliminación de copias de seguridad de WSS 3 y MOSS 2007 utilizando un script de Visual Basic

Autor: Gustavo

Escriba un comentario sobre este articulo

Nota: basado en el artículo de Conocimiento Básico de Microsoft numero 941330

Copias de seguridad pueden ser eliminadas manualmente, pero de esta forma no se limpia apropiadamente el archivo de manifiesto "spbrtoc.xml". Para hacerlo de forma correcta, utilice un escript de Visual Basic para eliminar las copias.

Para ejecutar el script necesita tener suficientes derechos; típicamente el usuario debe ser miembro del grupo local de administradores en el servidor con las copias y tener permisos de lectura, escritura y eliminación en el directorio correspondiente.

Advertencia: El script suministrado a continuación ha sido presentado por Microsoft solamente como ilustración, sin ninguna garantía implícita o explícita, y parte del precepto de que la persona que lo va a utilizar tiene suficientes conocimientos sobre programación y de SharePoint para poderlo ejecutar.

El siguiente script automatiza la eliminación de copias de seguridad más antiguas que la fecha determinada:

´       Title: BackupCleanUp
´ Description: Deletes SharePoint 2007 backups that are older than a specified 
´              number of days and then removes the backups from the backup history.

Dim nNumberOfDays
Dim strTOCFile
Dim dtDeleteDate

Set objXML = CreateObject("Microsoft.XMLDOM")
Set objFS  = CreateObject("Scripting.FileSystemObject")
Set objLog = objFS.OpenTextFile("BackupCleanUp.log",8,true)

´ Validate command line arguments and initialize data.
If WScript.Arguments.Count = 2 Then
    If IsNumeric(WScript.Arguments(0)) Then   
        nNumberOfDays = CInt(WScript.Arguments(0))
        dtDeleteDate = DateAdd("d",nNumberOfDays*-1,Now)
    Else
        WScript.Echo "<NumberOfDays> must be an integer value."
    End If
        strTOCFile = WScript.Arguments(1)
Else
    WScript.Echo "Usage: BackupCleanUp <NumberOfDays> <PathToTOC>"
    WScript.Quit
End If

objLog.WriteLine(Now() &vbTab& "Start: Clean up backups older than " &nNumberOfDays& " days from " &strTOCFile& ".")

´ Load the SharePoint backup and restore the TOC file.
objXML.Async = false
objXML.Load(strTOCFile)

If objXML.ParseError.ErrorCode <> 0 Then
    objLog.WriteLine(Now() &vbTab& "Error: Could not load the SharePoint Backup / Restore History." &vbCrLf&_
                     Now() &vbTab& "Reason: " &objXML.ParseError.Reason& ".") 
    WScript.Quit
End If

´ Delete backup nodes that are older than the deletion date.
For Each objNode in objXML.DocumentElement.ChildNodes
    If CDate(objNode.SelectSingleNode("SPFinishTime").Text) < dtDeleteDate Then
        If objNode.SelectSingleNode("SPIsBackup").Text = "True" Then
            objFS.DeleteFolder(objNode.SelectSingleNode("SPBackupDirectory").Text)
            objLog.WriteLine(Now() &vbTab& "Deleted: " &objNode.SelectSingleNode("SPBackupDirectory").Text& ".")
            objXML.DocumentElement.RemoveChild(objNode)
        End If     
    End If
Next

´ Save the XML file with the old nodes removed.
objXML.Save(strTOCFile)
objLog.WriteLine(Now() &vbTab& "Finish: Completed backup clean up.")

SkunkWorks SharePoint Portal

Automatizar la eliminación de copias de seguridad

Infraestructura